Scenario:
* Target computer has one adapter plugged into 10.11.x.x network, another unplugged.
* Push install fails. SMP log shows successful discovery:
===============
Discovered computer details: [<ComputerFQDN>] =>
name=<Computername> (<ComputerGUID>),
domain=SCEE, systype=Win64, os=Microsoft Windows Server 2016 Standard,
version=10.0.14393, fqdn=<ComputerFQDN>  ip={192.0.2.1}
===============
However, SMP is trying to push via IP of unplugged network adapter:
=================
Failed to copy the eXpress Client service to \\169.254.XXX.XXX\ADMIN$\AltirisAgentInstSvc.exe.
Error: The network path was not found.
=================

Failed to copy the eXpress Client service to \\169.254.XXX.XXX\ADMIN$\AltirisAgentInstSvc.exe. Error: The network path was not found.

ITMS 8.5RU2

Wrong order of IP addresses returned from database

Execute following script against CMDB database to alter stored procedure:

-------------

SET ANSI_NULLS ON
GO
SET QUOTED_IDENTIFIER ON
GO

alter proc dbo.spGetDiscoveryMachineInfo
       @resourceGuid uniqueidentifier
as
begin
       -- first set is basic info
       select
              [_ResourceGuid],
              [FQDN],
              [Name],
              [Domain],
              [OS Name],
              [OS Version],
              [System Type]
       from Inv_AeX_AC_Identification a where a._ResourceGuid = @resourceGuid

       -- to join from Agent Push and TCP4 tables
       declare @ips as table ([_id] int not null identity, [IP Address] nvarchar(65))

       -- Agent Push IP
       insert into @ips select [IP Address] from AgentPushData
              where [Guid] = @resourceGuid
                     and [IP Address] is not null
                     and [IP Address] != ''

       -- Inv_AeX_AC_TCPIP
       insert into @ips select t.[IP Address] from (
              select ip4.[IP Address], ip4.[Physical], ip4.[Routable] from Inv_AeX_AC_TCPIP ip4
              left join @ips i on i.[IP Address] = ip4.[IP Address]
              where ip4._ResourceGuid = @resourceGuid
                     and i.[IP Address] is null
       ) t order by t.[Physical] desc, t.[Routable] desc

       -- IPv4
       select [IP Address] from @ips
              order by _id asc
       
       -- IPv6
       select [IP Address] from Inv_AeX_AC_TCPIPv6 where _ResourceGuid = @resourceGuid
              order by [Physical] desc, [Routable] desc
end

-------------